PROC SQL Tutorial for Beginners (20 Examples)

This tutorial is designed for beginners who want to get started with PROC SQL. Also, it will attempt to compare the techniques of SAS DATA step and PROC SQL.

TERMINOLOGY

The difference between SAS and SQL terminology is shown in the table below.

SAS vs. SQL

Syntax: PROC SQL

The syntax of PROC SQL is as follows:

PROC SQL;
  SELECT column(s)
  FROM table(s) | view(s)
  WHERE expression
  GROUP BY column(s)
  HAVING expression
  ORDER BY column(s);
QUIT;

The SELECT statement must be specified in the following order:

1. SELECT
2. FROM
3. WHERE
4. GROUP BY
5. HAVING
6. ORDER BY

Note: SELECT FROM clauses are required. All the other clauses are optional.

To memorize the order of SQL queries, you can use the mnemonic "SFWGHO".

Tip to Memorize SQL Query Order

EXPLANATION

PROC SQL: calls the SQL procedure
SELECT: specifies the column(s) (variables) to be selected
FROM: specifies the table(s) (data sets) to be queried
WHERE: subsets the data based on a condition
GROUP BY: classifies the data into groups based on the specified column(s)
ORDER BY: sorts the resulting rows (observations) by the specified column(s)
QUIT: ends the PROC SQL procedure

We are going to look at the difference between Non-SQL Base SAS and PROC SQL.

SAS Functions & Procedures vs SQL Statements & Clauses

Important Terminology

You would hear the word 'schema' from SQL programmers. It refers todesign of database. In other words, it is the framework of database.

Prepare Dummy Data for Illustration
In the SAS program below, mylib is a name of permanent library which we are creating. Make sure you change the directory location of libname. We are using a sample of dataset which is stored in SASHELP library. This data set contains birth weight data.

libname mylib '/home/deepanshu/';
data mylib.outdata ;
 set SASHELP.BWEIGHT (obs=1000);
run;

PROC SQL STATEMENTS

1. How to select all variables from the data set

proc sql; 
 select * 
 from mylib.outdata;
Quit; 

Asterisk (*) is used to select all columns (variables) in the order in which they are stored in the table.
Outdata is the table (data set) from which we need to select the columns (variables). It is stored in MYLIB library.

To display the list of columns to the SAS log, use FEEDBACK option in the PROC SQL statement

proc sql feedback; 
 select * 
 from mylib.outdata;
Quit; 

The SAS log is shown below:

 71         proc sql feedback;
 72          select *
 73          from mylib.outdata;
 NOTE: Statement transforms to:
         select OUTDATA.Weight, OUTDATA.Black, OUTDATA.Married, OUTDATA.Boy, OUTDATA.MomAge, OUTDATA.MomSmoke, OUTDATA.CigsPerDay, 
 OUTDATA.MomWtGain, OUTDATA.Visit, OUTDATA.MomEdLevel
           from MYLIB.OUTDATA;
 74         Quit;

2. How to select specific variables from the data set

In the SELECT clause, multiple columns are separated by commas.

proc sql; 
 select weight,married 
 from mylib.outdata;
Quit; 

In the SELECT clause, Weight and Married columns (variables) are specified so that we can select them from OUTDATA table (data set).

3. How to limit the number of rows

Suppose you want to limit the number of rows (observations) that PROC SQL displays, use the OUTOBS= option in the PROC SQL statement.

proc sql outobs=50; 
 select weight,married 
 from mylib.outdata;
Quit; 

4. How to rename a variable in output

Suppose you want to rename a variable, use the column alias AS option in the PROC SQL statement.

options nolabel;
proc sql; 
 select weight,married as marriage
 from mylib.outdata;
Quit; 

The variable name has been renamed from married to marriage. options nolabel tells SAS not to use variable labels in SAS procedures. I used it so that you can see variable name has been changed to marriagae

5. How to create a new variable

Suppose you want to create a new variable that contains calculation.

proc sql; 
 select weight, (weight*0.5) as newweight
 from mylib.outdata;
Quit; 

A new variable has been created and named newweight which is calculated on the basis of the existing variable weight.

6. How to refer to a previously calculated variable

The keyword CALCULATED is used to refer a previously calculated variable.

proc sql; 
 select weight, (weight*0.5) as newweight, 
CALCULATED newweight*0.25 as revweight
 from mylib.outdata;
Quit; 

7. How to remove duplicate rows

The keyword DISTINCT is used to eliminate duplicate rows (observations) from your query results.

In the following program, we are asking SAS to remove all those cases where in duplicates exist on combination of both the variables - weight and married.

proc sql;
select DISTINCT weight, married
from mylib.outdata;
quit;

The DISTINCT * implies cases having same values in all the variables as a whole would be removed.

proc sql;
select DISTINCT *
from mylib.outdata;
quit;

8. How to label and format variables

SAS-defined formats can be used to improve the appearance of the body of a report. You can also label the variables using LABEL keyword.

options label;
proc sql; 
 select weight FORMAT= 8.2
, married Label =" Married People"
 from mylib.outdata;
Quit; 

9. How to sort data

The ORDER BY clause returns the data in sorted order.

ASC option is used to sort the data in ascending order. It is the default option.
DESC option is used to sort the data in descending order.

proc sql; 
 select MoMAge, eight, married
 from mylib.outdata
ORDER BY weight ASC, married DESC;
Quit;

10. How to filter data with the WHERE clause

Use the WHERE clause with any valid SAS expression to subset data.

List of conditional operators :

1. BETWEEN-AND

The BETWEEN-AND operator selects within an inclusive range of values.

Example : where salary between 4500 and 6000;

2. CONTAINS or ?

The CONTAINS or ? operator selects observations by searching for a specified set of characters within the values of a character variable

Example : where firstname contains 'DE';
OR where firstname ? 'DE';

3. IN

The IN operator selects from a list of fixed values.

Example : where state = 'NC' or state = 'TX';

The easier way to write the above statement would be to use the IN operator

where state IN ('NC','TX');

4. IS MISSING or IS NULL

The IS MISSING or IS NULL operator selects missing values.

Example : where dateofbirth is missing

OR where dateofbirth is null

5. LIKE

The LIKE Operator is used to select a pattern.





Important Point :

The WHERE clause can reference a previously calculated variable in two ways-

1. Use CALCULATED keyword.
2. Repeat the calculation in the WHERE clause.

Method I :

PROC SQL;
 SELECT momage,
 (WEIGHT * .01) AS NEWWEIGHT
 FROM mylib.outdata
 WHERE CALCULATED NEWWEIGHT > 5;
QUIT;

Method II :

PROC SQL;
 SELECT momage, (WEIGHT * .01) AS NEWWEIGHT
 FROM mylib.outdata
 WHERE (WEIGHT * .01) > 5;
QUIT;

11. How to write multiple conditions/criteria in PROC SQL?

The CASE WHEN statement is used in SQL to perform conditional logic and return different values based on specified conditions. The END statement is required when using the CASE WHEN statement.

PROC SQL;
 SELECT WEIGHT,
 CASE
 WHEN WEIGHT BETWEEN 0 AND 2000 THEN 'LOW'
 WHEN WEIGHT BETWEEN 2001 AND 3000 THEN 'MEDIUM'
 WHEN WEIGHT BETWEEN 3001 AND 4000 THEN 'HIGH'
 ELSE 'VERY HIGH'
 END AS NEWWEIGHT
 FROM mylib.outdata;
QUIT;

The conditions within the CASE statement are as follows:

1. If the weight is between 0 and 2000 (inclusive), it is categorized as 'LOW'.
2. If the weight is between 2001 and 3000 (inclusive), it is categorized as 'MEDIUM'.
3. If the weight is between 3001 and 4000 (inclusive), it is categorized as 'HIGH'.
4. If the weight does not fall into any of the above ranges, it is categorized as 'VERY HIGH'.

The following operators can be used in CASE expression:

• All operators that IF uses (=, <, >, NOT, NE, AND, OR, IN, etc)
• BETWEEN AND
• CONTAINS or '?' (wildcard operator)
• IS NULL or IS MISSING
• = *
• LIKE

12. How to summarize data

Use GROUP BY clause to summarize or aggregate data. Summary functions are used on the SELECT statement to produce summary for each of the analysis variables.

proc sql; 
 select momage, COUNT(married) AS marriage 
 from mylib.outdata
GROUP BY momage;
Quit;

The summary functions available are listed below:

1. AVG/MEAN
2. COUNT/FREQ/N
3. SUM
4. MAX
5. MIN
6. NMISS
7. STD
8. VAR
9. T (t value)
10. USS (Uncorrelated Sum of Square)
11. CSS (Correlated Sum of Square)
12. RANGE

13. How to filter data in the groups?

In order to subset data when grouping is in effect, the HAVING clause must be used.The variable specified in having clause must contain summary statistics.

proc sql; 
 select momage, weight, COUNT(married) AS marriage 
 from mylib.outdata
GROUP BY momage, weight
HAVING marriage > 2;
Quit;

Important Point -

The WHERE clause cannot be used to subset aggregated data. To subset data with the GROUP BY clause you must use HAVING clause.

14. How to create a new table

The CREATE TABLE statement can be used to create a new data set as output instead of a report produced in output window.

SYNTAX

PROC SQL;
CREATE TABLE table-name AS
SELECT column(s)
FROM table(s) | view(s)
WHERE expression
GROUP BY column(s)
ORDER BY column(s);
QUIT;

proc sql; 
create table health AS 
 select weight, married 
 from mylib.outdata
ORDER BY weight ASC, married DESC;
Quit; 

15. How to limit the number of rows in the newly created dataset?

Suppose you want to limit the number of rows (observations) that PROC SQL produces in the data set, use the INOBS= option in the PROC SQL statement.

proc sql INOBS=50; 
create table health AS 
select weight,married 
 from mylib.outdata;
Quit; 

Difference between INOBS= and OUTOBS=

INOBS controls how many records are read from the dataset and OUTOBS controls how many records are written. Run the following program and see the difference. Both returns different results.

/* OUTOBS=Example*/
proc sql outobs=2;
select age, count(*) as tot
from sashelp.class
group by age;
quit;
/* INOBS= Example */
proc sql inobs=4;
select age, count(*) as tot
from sashelp.class
group by age;
quit;

16. How to count unique values by a grouping variable

Suppose you are asked to calculate the unique number of age values by Sex columns using SASHELP.CLASS dataset

You can use PROC SQL with COUNT(DISTINCT variable_name) to determine the number of unique values for a column.

PROC SQL;
CREATE TABLE TEST1 as
SELECT Sex,
Count(distinct Age) AS Unique_count
FROM sashelp.class
GROUP BY Sex;
QUIT;

17. How to count the number of missing values

You can use NMISS() function to compute the number of missing values in a variable. The COUNT() function returns the number of non-missing values in a variable.

data temp;
input id;
cards;
1
2
.
4
5
.
;
run;

proc sql;
select nmiss(id) as N_missings,
count(id) as N,
calculated N_missings + calculated N as total
from temp;
quit;

Proc SQL : Number of Missing Values

How to refer to a calculated variable
The keyword CALCULATED is used to refer to a newly created variable for further calculation. In this case, we have used CALCULATED to sum 'N_MISSINGS' and 'N' variables.

18. KEEP and DROP some variables

Suppose you need to keep all the variables from SASHELP.CARS except variables 'MODEL' and 'MAKE'. The DROP= option is used to drop these two variables. Similarly, we can use KEEP= option to keep specific variables. These DROP= and KEEP= Options are not native SQL language. It only works in SAS.

proc sql;
create table saslearning (drop= make model) as
select * from sashelp.cars;
quit;

19. How to delete rows from a table

You can use DELETE FROM statement to remove records (rows) from a dataset.

proc sql;
delete from mylib.outdata
where momage > 0;
quit;

In this case, we are deleting all records having momage greater than 0 from outdata dataset. Log shows '478 rows were deleted from MYLIB.OUTDATA'.

20. How to use sub query in PROC SQL?

Suppose you need to find out employee IDs having records in the table named 'file1' but not in table 'file2'.

data file1;
input ID age;
cards;
1 24
2 34
3 45
4 67
;
run;
data file2;
input ID age;
cards;
1 25
3 46
4 62
;
run;
Proc SQL;
Select ID from file1
Where ID not in (select ID from file2);
Quit;

21. Sub Query - Example II

Find employee IDs whose age is in the average age +/- 10 years.

Proc SQL;
Select id from file1
where age between (select Avg(age) from file1) - 10 and
(select avg(age) from file1)+10;
Quit;

22. Sub Query - Example III

The CASE statement is used to evaluate a condition: whether a student has a score below 70 in any test. To achieve this, we have written a subquery that selects "Student_ID" from the "Tests" table where the "Score" is less than 70.

If the condition is true, the new column "Test_Results" is assigned the value 'Failed one or more tests.' If the condition is false, the value 'Passed all tests' is assigned to the "Test_Results" column. The result of the query will display the student's name, grade, teacher, and their test results.

proc sql;
select Name,Grade,Teacher,
Case
When Student_ID in
(select Student_ID from Tests where Score lt 70) then 'Failed one or more tests'
else 'Passed all tests'
end as Test_Results
from Students;
quit;

Next Lesson : PROC SQL Joins

Related Posts

SAS Tutorials : Top 100 SAS Tutorials

Proc SQL Tutorials : Top 15 Proc SQL Tutorials

Spread the Word!
Share Share Tweet

About Author:

Deepanshu founded ListenData with a simple objective - Make analytics easy to understand and follow. He has over 10 years of experience in data science. During his tenure, he worked with global clients in various domains like Banking, Insurance, Private Equity, Telecom and HR.

While I love having friends who agree, I only learn from those who don't
Let's Get Connected Email LinkedIn