3 Ways to Integrate ChatGPT into Excel

In this post, we will talk about how to integrate ChatGPT into MS Excel. Popularity of ChatGPT is growing day by day. It has a variety of use cases ranging from healthcare to banking domain.

OpenAI also has a public API which makes it easy to embed ChatGPT in any web application or software. They have an official python package for the same, but no Excel add-in for MS Excel users. Since web API is available, we can use it in MS Excel as well using VBA code. Some of the beginners may not familiar with VBA but with Excel Macros. VBA is basically a programming language used to create Excel Macros to automate repetitive tasks.

Benefits of using ChatGPT in Excel

There are numerous benefits of using ChatGPT within Excel. Some of them are as follows -

1. Insight Generation: By integrating ChatGPT into MS Excel, users can generate insights more easily, allowing them to identify trends and make informed decisions using Excel.
2. Automation: MS Excel has advanced capabilities to automate routine tasks. Using ChatGPT with Excel will improve productivity further.
3. Easy Editing: Easy to edit output (response) from ChatGPT in Excel.
4. Error detection and troubleshooting: Errors in Excel formulas can be frustrating and time consuming to debug. By integrating ChatGPT, you can use its capabilities to debug errors in your excel sheet.
5. Structured Output: Easy to record and organize data in a structured format, making it easier to share it with team members

Table of Contents

---

Steps to access ChatGPT API

Get API Key

The first and foremost step is to sign up using this link - platform.openai.com. You can do it easily through your existing Google or Microsoft account. Once done, you need to get secret API key to use API. It will look like this. Copy your API key for future reference.

sk-xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

Is ChatGPT API Free?

The ChatGPT Plugin for MS Excel is absolutely free to use and can run on any version of Excel. It does not even require an Excel 365 license. However, please note that the OpenAI API does have charges associated with it. The good news is that these charges are very low and affordable. These charges vary depending on how much you use the API. It means if you don't use the API at all in a particular month, you would not incur any charges for that month. I have been using it daily for the past few months, and it has cost me less than a dollar per month (precisely 50-65 cents per month). For detailed information about the pricing, it's recommended to refer to OpenAI's pricing documentation. Make sure not to share your API key with others. Otherwise, you will pay for other's usage.

Is ChatGPT API Safe for Your Data?

OpenAI's data privacy policy states that they do not train their models on any user data submitted through their API. The inputs and outputs of the API do not become part of training or building their models.

3 Methods to use ChatGPT in Excel

In this section we will cover various ways to use ChatGPT in Excel. You can decide your preferred one as per your requirement.

Method 1 : Excel Plugin for ChatGPT

The main benefit of excel plugin is that it is not dependent on one file like macro workbook and can be easily shared between different workbooks and users. You can download the excel plugin for ChatGPT by clicking on Download button. In Microsoft Excel, a plugin is referred to as an add-in. Don't get confused. Plugin and add-in are essentially the same in MS Excel.

This ChatGPT plugin is compatible with both Windows and macOS operating systems.

Demo Video : ChatGPT inside Excel

See the video below on how to use and install this add-in

How to install add-in

When you download add-in or macro file from internet, Microsoft blocks them from running and shows the source of this file is untrusted. You need to follow the steps below to make it working.

1. Go to the folder where the downloaded add-in file is located.
2. Right-click the file and choose Properties from the menu.
3. At the bottom of the General Tab, select the Unblock checkbox under security option and then click OK.

Refer the following steps to install ChatGPT add-in in MS Excel.

1. Open Excel and click on the File tab in the ribbon.
2. Click on Options and then select Add-ins from the left-hand menu.
3. In the Manage drop-down menu at the bottom of the screen, select Excel Add-ins and click on the Go button.
4. Click on the Browse button and locate the add-in file that you downloaded.
5. Select the add-in file and click on the OK button.
6. You should see the name of the add-in file in the Add-Ins dialog box. Check the box next to the add-in name to activate it.
7. Once you are done with the above steps, a new tab called ChatGPT should be visible in your Excel workbook.

How to use ChatGPT's Excel add-in

Follow the steps below to use ChatGPT add-in for MS Excel.

1. Open a new or existing MS Excel Workbook
2. Enter text you want to ask ChatGPT in any cell
3. Click on ChatGPT Tab > AI Assistant
4. Enter your API Key and select Model Type
5. Select the cell in which you entered text in step 2
6. Output will be generated and will appear within a few seconds.
7. When you want ChatGPT to run on multiple cells, you can use the AIAssistant function. See the details in the next section.

ChatGPT Excel Add-in : Functions

This add-in has the following functions that you can use to obtain responses from ChatGPT and enter them into Excel.

1. AIAssistant(text, [word_count]) : Generates and provides the output of the search query using ChatGPT.
   - text : Text you want to search
   - word_count : Optional. Specify the maximum number of words for the output generated by ChatGPT.
2. AIAssistant_Chat(text, [reset]) : Converse like ChatGPT website remembers prior conversations.
   - text : Text you want to search
   - reset : Optional. Start/Reset chat session.
3. AIAssistant_FillData(rng_existingdata, rng_fill) : Fill incomplete data by training ChatGPT on existing data.
   - rng_existingdata : Range of training data
   - rng_fill : Specify cell that needs to be filled in.
4. AIAssistant_Extractor(prompt, keyword) : Extract key data from ChatGPT. Key Data can be Name, Place, Organization details etc.
   - prompt : Specify the cell which contains text from which you want to extract key data.
   - keyword : keyword can be name, place, organisation etc.
5. AIAssistant_Translator(text, language) : It translates text from one language to another.
   - text : Specify cell that contains text that you want to translate.
   - language : Name of language. E.g. Spanish, French etc.
6. AIAssistant_Explain(cell_formula, [detail]) : Help you to explain Excel Formula which you don't understand and need support.
   - cell_formula : Cell that contains an Excel formula that you want ChatGPT to explain to you.
   - detail : Optional. Default value is TRUE. Set FALSE if you want less verbose reply.
7. AIAssistant_Insights(rng_data, [prompt]) : It generates data insights from the provided dataset.
   - rng_data : Specify cells containing data (including the header).
   - prompt : Optional. Provide specific information you want about the data.
8. AIAssistant_QnA(query, passage) : It provides an answer to a question from within a custom large text you provided.
   - query : Specify the cell containing a question.
   - passage : Specify the cell containing a large text.

To type the functions faster, first type =ai, then use the UP or DOWN arrow key to select the function you want, and finally press the Tab key.

Search with ChatGPT

The AIAssistant function uses ChatGPT to search for information and put the results in Excel. See the example below.

=AIAssistant("First President of US")

If you want to limit the response from ChatGPT to a maximum of 2 words, specify '2' as the second argument of the function. For example, =AIAssistant("First President of US", 2).

Recall ChatGPT Conversations

By default when we send API requests to OpenAI, it does not recall prior conversations. It considers every API request as a new chat. It means when it answers your current question, it does not remember your previous question.

To improve ChatGPT's ability to remember prior conversations, we can use the function AIAssistant_Chat(text, [reset]). Set second argument reset as TRUE to start/reset chat.

Note : Both of these functions AIAssistant() and AIAssistant_Chat() generate output for your search query. However AIAssistant_Chat() also allows ChatGPT to remember your prior conversations which increases the token usage and cost more. It is recommended to set the second argument of the function reset as TRUE when you do not need ChatGPT to recall your prior conversations.

Data Insights

Please follow the steps below to generate data insights or find hidden patterns in your data with this plugin.

1. Click on the Generate Insights button in the ChatGPT tab on the ribbon in Excel.
2. In the message dialog box, select cells containing data (including the header) and then click "OK". For example, A1:D101.
3. Wait for the insights generated from ChatGPT API.
4. In the message dialog box, select a cell where the output will be saved. For example, F2.
5. Select "yes" or "no" if you want the output to be populated in multiple rows or a single row.

You can also analyze data using the function AIAssistant_Insights(rng_data, [prompt]). The second argument of the function is optional, and by default, it extracts key insights from the data if you don't specify anything in the second argument. See the syntax of AIAssistant_Insights() function below.

=AIAssistant_Insights(A1:D101,"Generate Top 5 Insights")

Translate with ChatGPT

If you're looking to translate text using Excel Plugin, you should try the AIAssistant_Translator function. It uses ChatGPT to help you with accurate translations. Just enter the text you want to translate and the language name, it will use ChatGPT's language skills to give you translations.

=AIAssistant_Translator("Hi, How are you doing?", "german")

Extract Key Info

The AIAssistant_Extractor function can be used to fetch key information such as name, location etc from the text. For example, suppose you have text "Dave went to New York for studies" in cell B2. You want to extract name and location from the text. Enter the following formula in cells C2 and D2.

=AIAssistant_Extractor(B2,"name")
=AIAssistant_Extractor(B2,"location")

Fill Missing Data

The AIAssistant_FillData function can be used for a variety of purposes. See some of the real-world use cases below.

1. Sentiment Analysis You can label positive/negative/neutral sentiments on customer feedback data. You just need to provide a few labels in first argument of the function.
2. Industry/Sector Classification You have companies name and wish to find out their industries/sectors.
3. Text Patterns Extraction You have text data which contains both character and numeric values. By using this function, you can extract numeric values from the text.

Building a Q&A System

The AIAssistant_QnA function is used to build a question and answering system. You input a paragraph or a text document along with your question and it helps you find the relevant answer within that text. It can be useful for tasks like quickly extracting information from large text without the need to manually search through the text. See the example below.

=AIAssistant_QnA(query, passage)

Learn Excel Formulas

The AIAssistant_Explain function assists you in understanding any Excel formula. For example, let's say you have a formula in cell B2: =VLOOKUP(B2,$B$2:$D$5,2,FALSE). If you enter this formula =AIAssistant_Explain(B2) in cell C2, it will provide an explanation for the VLOOKUP function.

Handle Non-English Letters

Sometimes non-english letters do not get displayed correctly in the response coming from ChatGPT API. This issue is related to UTF-8 encoding. To fix this issue you can use CleanMsg(ChatGPT_response) function. Please refer to the example below.

=CleanMsg(AIAssistant("Write an Instagram post about 'Good morning' in Spanish"))

Documentation : To learn more about this add-in and the above functions in detail, you can visit this link - Documentation of Excel Add-in

If you are happy with the above add-in, you don't need to jump to the other below methods of integrating ChatGPT in Excel. The methods below are just alternatives of using add-in but they are less robust and include manual steps.

Method 2 : Excel Macro for ChatGPT

The VBA code below fetch responses from ChatGPT using API and put it into Excel. It also cleans the response from ChatGPT and put it in structured format so that formatting gets maintained. This lets users edit response easily and easy to reuse in any other document or spreadsheet.

This macro only works on Windows OS. If you want to integrate ChatGPT into MS Excel on Mac OS, please use the add-in designed for Mac. Please refer to the previous section of this article.

Sub chatGPT()
  
  Dim request As Object
  Dim response As String
  Dim text, API, api_key, DisplayText, error_result As String
  Dim status_code As Long
  Dim cellr As Range
  Dim prompt, rng As Range
  
  'API Info
  API = "https://api.openai.com/v1/chat/completions"
api_key = "sk-xxxxxxxxxxxxxxxxxxxxxxxxxx"

  If api_key = "" Then
        MsgBox "Error: API key is blank!"
        Exit Sub
    End If
    
  Set prompt = Range("B3")
  Set cellr = prompt.Offset(1, 0)
  Set rng = Range(prompt.Offset(1, 0), prompt.Offset(2000, 0))
  rng.Clear
    
  'Input Text
    If prompt.Value = "" Then
        MsgBox "Error: Cell " & prompt.Address(RowAbsolute:=False, ColumnAbsolute:=False) & " is blank!"
        Exit Sub
    End If

  text = Replace(prompt.Value, Chr(34), Chr(39))
  text = Replace(text, vbLf, " ")

  'Create an HTTP request object
  Set request = CreateObject("MSXML2.XMLHTTP")
  With request
     .Open "POST", API, False
     .setRequestHeader "Content-Type", "application/json"
     .setRequestHeader "Authorization", "Bearer " & api_key
     .send "{""model"": ""gpt-3.5-turbo"",  ""messages"": [{""content"":""" & text & """,""role"":""user""}]," _
          & """temperature"": 1, ""top_p"": 0.7, ""max_tokens"": 2048}"
   status_code = .Status
   response = .responseText
  End With

  'Extract content
  If status_code = 200 Then
    DisplayText = ExtractContent(response)
  Else
    DisplayText = ExtractError(response)
  End If
    
  'Put response
  cellr.Value = DisplayText
  
  'Split to multiple rows
  Call SplitTextToMultipleRows(cellr)
  rng.WrapText = True
    
  'Clean up the object
  Set request = Nothing

End Sub

Sub SplitTextToMultipleRows(cell As Range)
    Dim splitArr() As String
    Dim delimiter As String
    delimiter = "\n"
    
    splitArr = Split(cell.Value, delimiter)
    For i = LBound(splitArr) To UBound(splitArr)
        x = splitArr(i)
        If Left(Trim(x), 1) = "=" Then
            x = "'" & x
        End If
        cell.Offset(i, 0).Value = Replace(x, "\""", Chr(34))
    Next i
    
End Sub

Function ExtractContent(jsonString As String) As String
    Dim startPos As Long
    Dim endPos As Long
    Dim Content As String
    
    startPos = InStr(jsonString, """content"": """) + Len("""content"": """)
    endPos = InStr(startPos, jsonString, "},") - 2
    Content = Mid(jsonString, startPos, endPos - startPos)
    Content = Trim(Replace(Content, "\""", Chr(34)))
    
    'Fix for excel forumulas as response
    If Left(Trim(Content), 1) = "=" Then
      Content = "'" & Content
    End If
    
    Content = Replace(Content, vbCrLf, "")
    Content = Replace(Content, vbLf, "")
    Content = Replace(Content, vbCr, "")
    
    If Right(Content, 1) = """" Then
      Content = Left(Content, Len(Content) - 1)
    End If
    
    ExtractContent = Content

End Function

Function ExtractError(jsonString As String) As String
    Dim startPos As Long
    Dim endPos As Long
        startPos = InStr(jsonString, """message"": """) + Len("""message"": """)
        endPos = InStr(startPos, jsonString, """")
        If startPos > Len("""message"": """) And endPos > startPos Then
            ExtractError = Mid(jsonString, startPos, endPos - startPos)
        Else
            startPos = InStr(jsonString, """code"": """) + Len("""code"": """)
            endPos = InStr(startPos, jsonString, """")
            If startPos > Len("""code"": """) And endPos > startPos Then
              ExtractError = Mid(jsonString, startPos, endPos - startPos)
            Else
              ExtractError = "Unknown error"
            End If
        End If
End Function

Enter API Key and Prompt

1. You need to enter your API key in the code above in the variable api_key. This is the same secret key which we obtained in the previous step.
2. Enter your question (prompt) in cell B3 and then follow the steps below.

How to use VBA code

1. Press Alt+F11 to open the VBA editor.
2. Click Insert > Module to create a new module.
3. In the module, copy and paste the VBA code mentioned above.
4. Once you have entered the code, close the VBA editor.
5. Run the macro by pressing Alt+F8 or by going to the Developer tab > Macros and select the macro chatGPT and hit Run button.

Demo Output

Method 3 : Excel Function for ChatGPT

You can also run ChatGPT as an excel function. The benefit of running it as function is that you can paste it down on multiple cells. See the animated image below how to use the function.

Syntax of function is

AIAssistant(text, [word_count])

text : prompt. Question you want to ask.
word_count : optional. Maximum number of words in the response that will be generated.

In the example below as shown in image, we are extracting capital city of different countries. Since ChatGPT responses are generally in more words than are needed, we can limit to maximum number of words in the second argument of function.

Function AIAssistant(text As String, Optional word_count As Long = 0) As String
  
  Dim request As Object
  Dim response As String
  Dim API, api_key, DisplayText, error_result As String
  Dim startPos, endPos, status_code As Long
  Dim rng As Range
  
  'API Info
  API = "https://api.openai.com/v1/chat/completions"
api_key = "sk-xxxxxxxxxxxxxxxxxxxxxxxx"
  
  'Input Text
   If word_count > 0 Then
    text = text & ". Provide response in maximum " & word_count & " words"
   End If
  
  text = Replace(text, Chr(34), Chr(39))
  text = Replace(text, vbLf, " ")
          
  'Send request to API
  Set request = CreateObject("MSXML2.XMLHTTP")
  With request
     .Open "POST", API, False
     .setRequestHeader "Content-Type", "application/json"
     .setRequestHeader "Authorization", "Bearer " & api_key
     .send "{""model"": ""gpt-3.5-turbo"",  ""messages"": [{""content"":""" & text & """,""role"":""user""}]," _
          & """temperature"": 0.7, ""top_p"": 1, ""max_tokens"": 2048}"
   status_code = .Status
   response = .responseText
  End With
  
  'Parse response from API
  If status_code = 200 Then
    DisplayText = ExtractContent(response)
  Else
    DisplayText = ExtractError(response)
  End If
  
    If word_count > 0 And Right(DisplayText, 1) = "." Then
        DisplayText = Left(DisplayText, Len(DisplayText) - 1)
    Else
        DisplayText = DisplayText
    End If
  
  'Return result
  AIAssistant = DisplayText

End Function

Function ExtractContent(jsonString As String) As String
    Dim startPos As Long
    Dim endPos As Long
    Dim Content As String
    
    startPos = InStr(jsonString, """content"": """) + Len("""content"": """)
    endPos = InStr(startPos, jsonString, "},") - 2
    Content = Mid(jsonString, startPos, endPos - startPos)
    Content = Trim(Replace(Content, "\""", Chr(34)))
    
    'Fix for excel forumulas as response
    If Left(Trim(Content), 1) = "=" Then
      Content = "'" & Content
    End If
    
    Content = Replace(Content, vbCrLf, "")
    Content = Replace(Content, vbLf, "")
    Content = Replace(Content, vbCr, "")
    Content = Replace(Content, "\n", vbCrLf)
     
    If Right(Content, 1) = """" Then
      Content = Left(Content, Len(Content) - 1)
    End If
    
    ExtractContent = Content

End Function

Function ExtractError(jsonString As String) As String
    Dim startPos As Long
    Dim endPos As Long
        startPos = InStr(jsonString, """message"": """) + Len("""message"": """)
        endPos = InStr(startPos, jsonString, """")
        If startPos > Len("""message"": """) And endPos > startPos Then
            ExtractError = Mid(jsonString, startPos, endPos - startPos)
        Else
            startPos = InStr(jsonString, """code"": """) + Len("""code"": """)
            endPos = InStr(startPos, jsonString, """")
            If startPos > Len("""code"": """) And endPos > startPos Then
              ExtractError = Mid(jsonString, startPos, endPos - startPos)
            Else
              ExtractError = "Unknown error"
            End If
        End If
End Function

Make sure you enter your API key highlighted in bold above.

Follow the steps 1 to 4 in the previous section "How to use VBA Code". Once you are through with these 4 steps, type =AIAssistant(B3) in any cell. Here B3 refers to the cell wherein your prompt (question) is placed.

How to use GPT-4

To access GPT-4, you can replace gpt-3.5-turbo with gpt-4 in the above VBA code. The OpenAI Team regularly updates their models and they have various versions of them but they make sure that users get the latest model version in gpt-4 or gpt-3.5-turbo.

How to handle large number of prompts

Suppose you have more than 100 prompts distributed across 100 cells in an Excel sheet, and you want to get answers for each question using ChatGPT. If you attempt to do this all at once by dragging the AIAssistant function to 100 rows, it may cause Excel to slow down or show errors because it can't handle so many requests together.

To solve this problem, you can try a different approach. Instead of asking all the questions to ChatGPT at once, you can ask one question at a time and get its answer. Then move on to the next question and repeat the process. In the code below, we assumed prompts starting from cell B3.

Sub AIAssistantLoop()

Dim ws As Worksheet
Dim promptColumn As String
Dim promptRng As String
Dim startRow As Long
Dim cell As Range
Dim result As Variant
Dim lastRow As Long

' Set the active sheet as the working sheet
Set ws = ActiveSheet

' Set the column having prompts. For e.g., prompts starting from cell B3
promptColumn = "B"
startRow = 3

' Find the last row in column
lastRow = ws.Cells(ws.Rows.Count, promptColumn).End(xlUp).Row

' Loop through cells to the last row
promptRng = promptColumn & startRow & ":" & promptColumn & lastRow
For Each cell In ws.Range(promptRng)

    ' Check if the cell is not empty
    If Not IsEmpty(cell.Value) Then
    
        ' Call the AIAssistant function with the cell value
        result = Application.Run("AIAssistant", cell.Value)
        
        ' Paste the value back into the adjacent column
        cell.Offset(0, 1).Value = result
    
    End If

Next cell

End Sub

The code above uses the AIAssistant function from the add-in. If you want to include the second parameter word_count, use this Application.Run("AIAssistant", cell.Value, 2) instead of Application.Run("AIAssistant", cell.Value). Here 2 is set as word_count. Similarly, if you also want to use CleanMsg function, use this Application.Run("CleanMsg", Application.Run("AIAssistant", cell.Value))

If you want to use the function of Method III rather than the function from add-in, replace Application.Run("AIAssistant", cell.Value) with AIAssistant(cell.Value)

Follow the steps below to run the code.

1. Open the VBA editor by pressing Alt+F11.
2. Create a new module by clicking Insert > Module.
3. In the module, copy and paste the above VBA code. Then, close the VBA editor.
4. Execute the macro by pressing Alt+F8, selecting the macro AIAssistantLoop, and clicking the Run button.

How to use ChatGPT to write Excel formulas

You can also use the above add-in or macro and ask ChatGPT to act like an excel tutor. Within excel, you may be interested to know about excel functions, macros or other features related to data analysis. People who want to use Excel but don't know much about it are likely to find it really helpful. It not only saves your time but also makes data analysis easier. See the example below wherein we asked ChatGPT about simple excel related question.

=AIAssistant("Excel formula for 'Pass' if a value in cell F5 is less than 70, else 'Fail'")

ChatGPT Prompts for Excel formulas

Here are some examples that you can use to ask ChatGPT to write an Excel formula for you.

1. Write an Excel formula to count the number of cells in the range B2:B10 that contain the value "Pass".
2. I am working on a project. I am asked to analyze stock prices. How can I create an Excel formula to calculate the percentage change between two consecutive days' closing prices, assuming prices in cells B1 and B2?
3. I have a dataset with sales figures in column A and corresponding dates in column B. How can I use an Excel formula to calculate the total sales for October 2022?
4. In my sales data, I want to calculate the total sales for a 'Product A'. Sales value in the range A1:A10. Product names in range B2:B20. How can I write an Excel formula for this?
5. I am trying to manage my budget and want to know the percentage of expenses compared to my total budget. Can you help me create an Excel formula for this?
6. I have numbers for revenue in different months. How can I use an Excel formula to calculate the rate of growth from month to month?
7. I am working with employee data and need to find the average salary for employees in the 'Sales' department. How do I make an Excel formula for this given Salary in range B2:B20 and Department in range A2:A20?
8. In my sales report, I need to calculate the commission for each salesperson based on their performance. How can I create an Excel formula that considers different commission rates for different sales levels?
9. I have an Excel sheet with student grades as percentages. I need to assign letter grades based on these percentages. Can you show me how to create an Excel formula for this?

How to use ChatGPT to write VBA Code

It also works well for advanced excel concepts like macros. It can write VBA code for you. Writing VBA code has never been easier before with ChatGPT.

=AIAssistant("Write VBA code to apply filter on sheet1 and paste filtered rows to sheet2")

ChatGPT prompts for writing VBA Code

Here are a few examples that you can use to request ChatGPT to help you write VBA Code.

1. How can I loop through cells A1 to A10 in VBA?
2. How can I create a user-defined function in VBA to calculate the factorial?
3. How do I create a message box in VBA?
4. How to implement error handling in VBA for a specific block of code?
5. VBA code to copy cells A1 to A10 from one worksheet to another?
6. How can I format cells B2 to B5 in Excel using VBA to apply bold font and a specific background color?
7. How do I add or subtract days from a specific date in VBA?
8. How can I prompt the user for input and store the value in a variable in VBA?

How to fine tune ChatGPT response

You would find temperature parameter in the VBA code. It lies between 0 and 2. Higher values like 1.2 will generate the output more random, while lower values like 0.2 will be more focused.

How to fix errors

1. Error: You exceeded your current quota, please check your plan and billing details : To resolve this error, you need to switch to a paid account where you will be charged based on your API usage.

1. Go to OpenAI's website
2. Log in with your account and then navigate to Billing page.
3. Sign up for the Pay as you go plan by adding your debit/credit card.

If you are already on this plan, it means that you are making a large number of requests to ChatGPT, which it is unable to handle. OR your limit may be set too low. You can check your current quota in your account settings.

2. If you are getting this error - The model: gpt-4 does not exist it means you don't have access to GPT-4 API. You need to join waitlist for it. It does not matter if you have ChatGPT Plus subscription or not. Having a ChatGPT Plus subscription does not automatically grant access to the GPT-4 API.

3. If you are getting this error Invalid procedure call or argument, you need to add this MsgBox .Status before this line of code response = .responsetext to debug it. If the message box returns a value other than 200, it indicates that your request was not sent successfully. It must be 200 for the successful request. See the possible errors below.

1. 401 error code means either your API key is not correct, expired or you don't have access to specific version of ChatGPT Model.
2. 400 error code means your question (in cell B3) contains some invalid characters, possibly line breaks (string in multiple lines). To fix line breaks, add this line text = Replace(text, vbLf, " ") before Set request = CreateObject("MSXML2.XMLHTTP")
3. 404 error code may refer to typo in putting the model name incase you put something else other than gpt-3.5-turbo and gpt-4
4. 429 error code means you exceeded your current quota, please check your plan and billing details.

4. If you encounter any issue related to VBA references, try to add Microsoft XML, v 3.0. I am using Office 2019 in which the above code works without it. References I am using are as shown below. References can be added by opening VBA Editor and then Tools > References.

Refer the detailed guide about how to run ChatGPT in MS Word and PowerPoint
ChatGPT Plugin for MS Word
ChatGPT Plugin for MS PowerPoint.

Related Posts

Excel Tutorials : Top 100 Excel Tutorials

Spread the Word!
Share Share Tweet

About Author:

Deepanshu founded ListenData with a simple objective - Make analytics easy to understand and follow. He has over 10 years of experience in data science. During his tenure, he worked with global clients in various domains like Banking, Insurance, Private Equity, Telecom and HR.

While I love having friends who agree, I only learn from those who don't
Let's Get Connected Email LinkedIn